CMakeCPackOptions.cmake.in

   1 # This file is configured at cmake time, and loaded at cpack time.
   2 # To pass variables to cpack from cmake, they must be configured
   3 # in this file.
   4
   5 if(CPACK_GENERATOR MATCHES "NSIS")
   6   set(CPACK_NSIS_INSTALL_ROOT "@CPACK_NSIS_INSTALL_ROOT@")
   7
   8   # set the install/unistall icon used for the installer itself
   9   # There is a bug in NSI that does not handle full unix paths properly.
  10   set(CPACK_NSIS_MUI_ICON "@CMake_SOURCE_DIR@/Utilities/Release\\CMakeLogo.ico")
  11   set(CPACK_NSIS_MUI_UNIICON "@CMake_SOURCE_DIR@/Utilities/Release\\CMakeLogo.ico")
  12   # set the package header icon for MUI
  13   set(CPACK_PACKAGE_ICON "@CMake_SOURCE_DIR@/Utilities/Release\\CMakeInstall.bmp")
  14   # tell cpack to create links to the doc files
  15   set(CPACK_NSIS_MENU_LINKS
  16     "doc/cmake-@CMake_VERSION_MAJOR@.@CMake_VERSION_MINOR@/cmake-gui.html" "cmake-gui Help"
  17     "doc/cmake-@CMake_VERSION_MAJOR@.@CMake_VERSION_MINOR@/cmake.html" "CMake Help"
  18     "doc/cmake-@CMake_VERSION_MAJOR@.@CMake_VERSION_MINOR@/cmake-properties.html"
  19     "CMake Properties and Variables Help"
  20     "doc/cmake-@CMake_VERSION_MAJOR@.@CMake_VERSION_MINOR@/ctest.html" "CTest Help"
  21     "doc/cmake-@CMake_VERSION_MAJOR@.@CMake_VERSION_MINOR@/cmake-modules.html" "CMake Modules Help"
  22     "doc/cmake-@CMake_VERSION_MAJOR@.@CMake_VERSION_MINOR@/cmake-commands.html" "CMake Commands Help"
  23     "doc/cmake-@CMake_VERSION_MAJOR@.@CMake_VERSION_MINOR@/cpack.html" "CPack Help"
  24     "http://www.cmake.org" "CMake Web Site"
  25     )
  26   # Use the icon from cmake-gui for add-remove programs
  27   set(CPACK_NSIS_INSTALLED_ICON_NAME "bin\\cmake-gui.exe")
  28
  29   set(CPACK_NSIS_PACKAGE_NAME "@CPACK_NSIS_PACKAGE_NAME@")
  30   set(CPACK_NSIS_DISPLAY_NAME "@CPACK_NSIS_PACKAGE_NAME@, a cross-platform, open-source build system")
  31   set(CPACK_NSIS_HELP_LINK "http://www.cmake.org")
  32   set(CPACK_NSIS_URL_INFO_ABOUT "http://www.kitware.com")
  33   set(CPACK_NSIS_CONTACT @CPACK_PACKAGE_CONTACT@)
  34   set(CPACK_NSIS_MODIFY_PATH ON)
  35 endif()
  36
  37 # include the cpack options for qt dialog if they exisit
  38 # they might not if qt was not enabled for the build
  39 include("@QT_DIALOG_CPACK_OPTIONS_FILE@" OPTIONAL)
  40
  41 if(CPACK_GENERATOR MATCHES "CygwinSource")
  42   # when packaging source make sure the .build directory is not included
  43     set(CPACK_SOURCE_IGNORE_FILES
  44       "/CVS/" "/\\.build/" "/\\.svn/" "\\.swp$" "\\.#" "/#" "~$")
  45 endif()
  46
  47 if("${CPACK_GENERATOR}" STREQUAL "PackageMaker")
  48   if(CMAKE_PACKAGE_QTGUI)
  49     set(CPACK_PACKAGE_DEFAULT_LOCATION "/Applications")
  50   else()
  51     set(CPACK_PACKAGE_DEFAULT_LOCATION "/usr")
  52   endif()
  53 endif()
  54
  55 if("${CPACK_GENERATOR}" STREQUAL "WIX")
  56   # Reset CPACK_PACKAGE_VERSION to deal with WiX restriction.
  57   # But the file names still use the full CMake_VERSION value:
  58   set(CPACK_PACKAGE_FILE_NAME
  59     "${CPACK_PACKAGE_NAME}-@CMake_VERSION@-${CPACK_SYSTEM_NAME}")
  60   set(CPACK_SOURCE_PACKAGE_FILE_NAME
  61     "${CPACK_PACKAGE_NAME}-@CMake_VERSION@-Source")
  62
  63   if(NOT CPACK_WIX_SIZEOF_VOID_P)
  64     set(CPACK_WIX_SIZEOF_VOID_P "@CMAKE_SIZEOF_VOID_P@")
  65   endif()
  66
  67   set(CPACK_PACKAGE_VERSION
  68     "@CMake_VERSION_MAJOR@.@CMake_VERSION_MINOR@.@CMake_VERSION_PATCH@")
  69   # WIX installers require at most a 4 component version number, where
  70   # each component is an integer between 0 and 65534 inclusive
  71   set(tweak "@CMake_VERSION_TWEAK@")
  72   if(tweak MATCHES "^[0-9]+$")
  73     if(tweak GREATER 0 AND tweak LESS 65535)
  74       set(CPACK_PACKAGE_VERSION "${CPACK_PACKAGE_VERSION}.${tweak}")
  75     endif()
  76   endif()
  77 endif()