CMakeCPack.cmake

   1 #=============================================================================
   2 # CMake - Cross Platform Makefile Generator
   3 # Copyright 2000-2009 Kitware, Inc., Insight Software Consortium
   4 #
   5 # Distributed under the OSI-approved BSD License (the "License");
   6 # see accompanying file Copyright.txt for details.
   7 #
   8 # This software is distributed WITHOUT ANY WARRANTY; without even the
   9 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  10 # See the License for more information.
  11 #=============================================================================
  12
  13 # If the cmake version includes cpack, use it
  14 if(EXISTS "${CMAKE_ROOT}/Modules/CPack.cmake")
  15   if(EXISTS "${CMAKE_ROOT}/Modules/InstallRequiredSystemLibraries.cmake")
  16     option(CMAKE_INSTALL_DEBUG_LIBRARIES
  17       "Install Microsoft runtime debug libraries with CMake." FALSE)
  18     mark_as_advanced(CMAKE_INSTALL_DEBUG_LIBRARIES)
  19
  20     # By default, do not warn when built on machines using only VS Express:
  21     if(NOT DEFINED CMAKE_INSTALL_SYSTEM_RUNTIME_LIBS_NO_WARNINGS)
  22       set(CMAKE_INSTALL_SYSTEM_RUNTIME_LIBS_NO_WARNINGS ON)
  23     endif()
  24
  25     include(${CMake_SOURCE_DIR}/Modules/InstallRequiredSystemLibraries.cmake)
  26   endif()
  27
  28   set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "CMake is a build tool")
  29   set(CPACK_PACKAGE_VENDOR "Kitware")
  30   set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/Copyright.txt")
  31   set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/Copyright.txt")
  32   set(CPACK_PACKAGE_VERSION "${CMake_VERSION}")
  33   set(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${CMake_VERSION_MAJOR}.${CMake_VERSION_MINOR}")
  34   set(CPACK_SOURCE_PACKAGE_FILE_NAME "cmake-${CMake_VERSION}")
  35
  36   # Make this explicit here, rather than accepting the CPack default value,
  37   # so we can refer to it:
  38   set(CPACK_PACKAGE_NAME "${CMAKE_PROJECT_NAME}")
  39
  40   # Installers for 32- vs. 64-bit CMake:
  41   #  - Root install directory (displayed to end user at installer-run time)
  42   #  - "NSIS package/display name" (text used in the installer GUI)
  43   #  - Registry key used to store info about the installation
  44   if(CMAKE_CL_64)
  45     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
  46     set(CPACK_NSIS_PACKAGE_NAME "${CPACK_PACKAGE_INSTALL_DIRECTORY} (Win64)")
  47     set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "${CPACK_PACKAGE_NAME} ${CPACK_PACKAGE_VERSION} (Win64)")
  48   else()
  49     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES")
  50     set(CPACK_NSIS_PACKAGE_NAME "${CPACK_PACKAGE_INSTALL_DIRECTORY}")
  51     set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "${CPACK_PACKAGE_NAME} ${CPACK_PACKAGE_VERSION}")
  52   endif()
  53
  54   if(NOT DEFINED CPACK_SYSTEM_NAME)
  55     # make sure package is not Cygwin-unknown, for Cygwin just
  56     # cygwin is good for the system name
  57     if("${CMAKE_SYSTEM_NAME}" STREQUAL "CYGWIN")
  58       set(CPACK_SYSTEM_NAME Cygwin)
  59     else()
  60       set(CPACK_SYSTEM_NAME ${CMAKE_SYSTEM_NAME}-${CMAKE_SYSTEM_PROCESSOR})
  61     endif()
  62   endif()
  63   if(${CPACK_SYSTEM_NAME} MATCHES Windows)
  64     if(CMAKE_CL_64)
  65       set(CPACK_SYSTEM_NAME win64-x64)
  66     else()
  67       set(CPACK_SYSTEM_NAME win32-x86)
  68     endif()
  69   endif()
  70
  71   if(NOT DEFINED CPACK_PACKAGE_FILE_NAME)
  72     # if the CPACK_PACKAGE_FILE_NAME is not defined by the cache
  73     # default to source package - system, on cygwin system is not
  74     # needed
  75     if(CYGWIN)
  76       set(CPACK_PACKAGE_FILE_NAME "${CPACK_SOURCE_PACKAGE_FILE_NAME}")
  77     else()
  78       set(CPACK_PACKAGE_FILE_NAME
  79         "${CPACK_SOURCE_PACKAGE_FILE_NAME}-${CPACK_SYSTEM_NAME}")
  80     endif()
  81   endif()
  82
  83   set(CPACK_PACKAGE_CONTACT "cmake@cmake.org")
  84
  85   if(UNIX)
  86     set(CPACK_STRIP_FILES "bin/ccmake;bin/cmake;bin/cpack;bin/ctest")
  87     set(CPACK_SOURCE_STRIP_FILES "")
  88     set(CPACK_PACKAGE_EXECUTABLES "ccmake" "CMake")
  89   endif()
  90
  91   # cygwin specific packaging stuff
  92   if(CYGWIN)
  93     # setup the cygwin package name
  94     set(CPACK_PACKAGE_NAME cmake)
  95     # setup the name of the package for cygwin cmake-2.4.3
  96     set(CPACK_PACKAGE_FILE_NAME
  97       "${CPACK_PACKAGE_NAME}-${CMake_VERSION}")
  98     # the source has the same name as the binary
  99     set(CPACK_SOURCE_PACKAGE_FILE_NAME ${CPACK_PACKAGE_FILE_NAME})
 100     # Create a cygwin version number in case there are changes for cygwin
 101     # that are not reflected upstream in CMake
 102     set(CPACK_CYGWIN_PATCH_NUMBER 1 CACHE STRING "patch number for CMake cygwin packages")
 103     mark_as_advanced(CPACK_CYGWIN_PATCH_NUMBER)
 104     # These files are required by the cmCPackCygwinSourceGenerator and the files
 105     # put into the release tar files.
 106     set(CPACK_CYGWIN_BUILD_SCRIPT
 107       "${CMake_BINARY_DIR}/${CPACK_PACKAGE_FILE_NAME}-${CPACK_CYGWIN_PATCH_NUMBER}.sh")
 108     set(CPACK_CYGWIN_PATCH_FILE
 109       "${CMake_BINARY_DIR}/${CPACK_PACKAGE_FILE_NAME}-${CPACK_CYGWIN_PATCH_NUMBER}.patch")
 110     # include the sub directory cmake file for cygwin that
 111     # configures some files and adds some install targets
 112     # this file uses some of the package file name variables
 113     include(Utilities/Release/Cygwin/CMakeLists.txt)
 114   endif()
 115
 116   # Set the options file that needs to be included inside CMakeCPackOptions.cmake
 117   set(QT_DIALOG_CPACK_OPTIONS_FILE ${CMake_BINARY_DIR}/Source/QtDialog/QtDialogCPack.cmake)
 118   configure_file("${CMake_SOURCE_DIR}/CMakeCPackOptions.cmake.in"
 119     "${CMake_BINARY_DIR}/CMakeCPackOptions.cmake" @ONLY)
 120   set(CPACK_PROJECT_CONFIG_FILE "${CMake_BINARY_DIR}/CMakeCPackOptions.cmake")
 121
 122   # include CPack model once all variables are set
 123   include(CPack)
 124 endif()