CMakeCPack.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4 option(CMAKE_INSTALL_DEBUG_LIBRARIES
   5   "Install Microsoft runtime debug libraries with CMake." FALSE)
   6 mark_as_advanced(CMAKE_INSTALL_DEBUG_LIBRARIES)
   7
   8 # By default, do not warn when built on machines using only VS Express:
   9 if(NOT DEFINED CMAKE_INSTALL_SYSTEM_RUNTIME_LIBS_NO_WARNINGS)
  10   set(CMAKE_INSTALL_SYSTEM_RUNTIME_LIBS_NO_WARNINGS ON)
  11 endif()
  12
  13 if(CMake_INSTALL_DEPENDENCIES)
  14   include(${CMake_SOURCE_DIR}/Modules/InstallRequiredSystemLibraries.cmake)
  15 endif()
  16
  17 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "CMake is a build tool")
  18 set(CPACK_PACKAGE_VENDOR "Kitware")
  19 set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/Copyright.txt")
  20 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/Copyright.txt")
  21 set(CPACK_PACKAGE_NAME "${CMAKE_PROJECT_NAME}")
  22 set(CPACK_PACKAGE_VERSION "${CMake_VERSION}")
  23 set(CPACK_PACKAGE_INSTALL_DIRECTORY "${CPACK_PACKAGE_NAME}")
  24 set(CPACK_SOURCE_PACKAGE_FILE_NAME "cmake-${CMake_VERSION}")
  25
  26 # Installers for 32- vs. 64-bit CMake:
  27 #  - Root install directory (displayed to end user at installer-run time)
  28 #  - "NSIS package/display name" (text used in the installer GUI)
  29 #  - Registry key used to store info about the installation
  30 if(CMAKE_CL_64)
  31   set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
  32   set(CPACK_NSIS_PACKAGE_NAME "${CPACK_PACKAGE_NAME} ${CPACK_PACKAGE_VERSION} (Win64)")
  33 else()
  34   set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES")
  35   set(CPACK_NSIS_PACKAGE_NAME "${CPACK_PACKAGE_NAME} ${CPACK_PACKAGE_VERSION}")
  36 endif()
  37 set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "${CPACK_NSIS_PACKAGE_NAME}")
  38
  39 if(NOT DEFINED CPACK_SYSTEM_NAME)
  40   # make sure package is not Cygwin-unknown, for Cygwin just
  41   # cygwin is good for the system name
  42   if("x${CMAKE_SYSTEM_NAME}" STREQUAL "xCYGWIN")
  43     set(CPACK_SYSTEM_NAME Cygwin)
  44   else()
  45     set(CPACK_SYSTEM_NAME ${CMAKE_SYSTEM_NAME}-${CMAKE_SYSTEM_PROCESSOR})
  46   endif()
  47 endif()
  48 if(${CPACK_SYSTEM_NAME} MATCHES Windows)
  49   if(CMAKE_CL_64)
  50     set(CPACK_SYSTEM_NAME win64-x64)
  51     set(CPACK_IFW_TARGET_DIRECTORY "@RootDir@/Program Files/${CMAKE_PROJECT_NAME}")
  52   else()
  53     set(CPACK_SYSTEM_NAME win32-x86)
  54   endif()
  55 endif()
  56
  57 # Command for configure IFW script templates
  58 include(${CMake_SOURCE_DIR}/Modules/CPackIFWConfigureFile.cmake)
  59
  60 # Advanced IFW configuration
  61 set(_cpifwrc CPACK_IFW_COMPONENT_GROUP_CMAKE_)
  62 set(_cpifwrcconf _CPACK_IFW_COMPONENT_GROUP_CMAKE)
  63 set(${_cpifwrcconf} "# CMake IFW configuration\n")
  64 macro(_cmifwarg DESCRIPTION TYPE NAME DEFAULT)
  65   set(_var CMake_IFW_ROOT_COMPONENT_${NAME})
  66   if(DEFINED ${_var})
  67     set(${_var} ${${_var}} CACHE ${TYPE} ${DESCRIPTION})
  68     mark_as_advanced(${_var})
  69   elseif(NOT "${DEFAULT}" STREQUAL "")
  70     set(${_var} ${DEFAULT})
  71   endif()
  72   if(DEFINED ${_var})
  73     set(${_cpifwrcconf}
  74       "${${_cpifwrcconf}}  set(${_cpifwrc}${NAME}\n    \"${${_var}}\")\n")
  75   endif()
  76 endmacro()
  77
  78 _cmifwarg("Package <Name> tag (domen-like)"
  79   STRING NAME "")
  80 _cmifwarg("Package <DisplayName> tag"
  81   STRING DISPLAY_NAME "")
  82 _cmifwarg("Package <Description> tag"
  83   STRING DESCRIPTION "")
  84 _cmifwarg("Package <ReleaseDate> tag (keep empty to auto generate)"
  85   STRING RELEASE_DATE "")
  86 _cmifwarg("Package <Default> tag (values: TRUE, FALSE, SCRIPT)"
  87   STRING DEFAULT "")
  88 _cmifwarg("Package <Version> tag"
  89   STRING VERSION
  90   "${CMake_VERSION_MAJOR}.${CMake_VERSION_MINOR}.${CMake_VERSION_PATCH}")
  91 _cmifwarg("Package <SortingPriority> tag"
  92   STRING PRIORITY "100")
  93 _cmifwarg("Package <ForsedInstallation> tag"
  94   STRING FORCED_INSTALLATION "")
  95
  96 set(${_cpifwrc}LICENSES_DEFAULT
  97   "${CPACK_PACKAGE_NAME} Copyright;${CPACK_RESOURCE_FILE_LICENSE}")
  98
  99 # Components
 100 if(CMake_INSTALL_COMPONENTS)
 101   set(_CPACK_IFW_COMPONENTS_ALL cmake ctest cpack)
 102   if(WIN32 AND NOT CYGWIN)
 103       list(APPEND _CPACK_IFW_COMPONENTS_ALL cmcldeps)
 104   endif()
 105   if(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME)
 106     set(_CPACK_IFW_COMPONENT_UNSPECIFIED_NAME
 107       ${CMAKE_INSTALL_DEFAULT_COMPONENT_NAME})
 108   else()
 109     set(_CPACK_IFW_COMPONENT_UNSPECIFIED_NAME Unspecified)
 110   endif()
 111   list(APPEND _CPACK_IFW_COMPONENTS_ALL ${_CPACK_IFW_COMPONENT_UNSPECIFIED_NAME})
 112   string(TOUPPER "${_CPACK_IFW_COMPONENT_UNSPECIFIED_NAME}"
 113     _CPACK_IFW_COMPONENT_UNSPECIFIED_UNAME)
 114   if(BUILD_CursesDialog)
 115     list(APPEND _CPACK_IFW_COMPONENTS_ALL ccmake)
 116   endif()
 117   if(BUILD_QtDialog)
 118     list(APPEND _CPACK_IFW_COMPONENTS_ALL cmake-gui)
 119     if(USE_LGPL)
 120       set(_CPACK_IFW_COMPONENT_CMAKE-GUI_LICENSES "set(CPACK_IFW_COMPONENT_CMAKE-GUI_LICENSES
 121   \"LGPLv${USE_LGPL}\" \"${CMake_SOURCE_DIR}/Licenses/LGPLv${USE_LGPL}.txt\")")
 122     endif()
 123   endif()
 124   if(SPHINX_MAN)
 125     list(APPEND _CPACK_IFW_COMPONENTS_ALL sphinx-man)
 126   endif()
 127   if(SPHINX_HTML)
 128     list(APPEND _CPACK_IFW_COMPONENTS_ALL sphinx-html)
 129   endif()
 130   if(SPHINX_SINGLEHTML)
 131     list(APPEND _CPACK_IFW_COMPONENTS_ALL sphinx-singlehtml)
 132   endif()
 133   if(SPHINX_QTHELP)
 134     list(APPEND _CPACK_IFW_COMPONENTS_ALL sphinx-qthelp)
 135   endif()
 136   if(SPHINX_LATEXPDF)
 137     list(APPEND _CPACK_IFW_COMPONENTS_ALL sphinx-latexpdf)
 138   endif()
 139   if(CMake_BUILD_DEVELOPER_REFERENCE)
 140     if(CMake_BUILD_DEVELOPER_REFERENCE_HTML)
 141       list(APPEND _CPACK_IFW_COMPONENTS_ALL cmake-developer-reference-html)
 142     endif()
 143     if(CMake_BUILD_DEVELOPER_REFERENCE_QTHELP)
 144       list(APPEND _CPACK_IFW_COMPONENTS_ALL cmake-developer-reference-qthelp)
 145     endif()
 146   endif()
 147   set(_CPACK_IFW_COMPONENTS_CONFIGURATION "
 148   # Components
 149   set(CPACK_COMPONENTS_ALL \"${_CPACK_IFW_COMPONENTS_ALL}\")
 150   set(CPACK_COMPONENTS_GROUPING IGNORE)
 151   ")
 152   _cmifwarg("Package <Script> template"
 153     FILEPATH SCRIPT_TEMPLATE "${CMake_SOURCE_DIR}/Source/QtIFW/CMake.qs.in")
 154 else()
 155   if(BUILD_QtDialog AND USE_LGPL)
 156     set(${_cpifwrc}LICENSES_DEFAULT
 157       "${${_cpifwrc}LICENSES_DEFAULT};LGPLv${USE_LGPL};${CMake_SOURCE_DIR}/Licenses/LGPLv${USE_LGPL}.txt")
 158   endif()
 159   _cmifwarg("Package <Script> template"
 160     FILEPATH SCRIPT_TEMPLATE "${CMake_SOURCE_DIR}/Source/QtIFW/installscript.qs.in")
 161 endif()
 162 _cmifwarg("Package <Script> generated"
 163   FILEPATH SCRIPT_GENERATED "${CMake_BINARY_DIR}/CMake.qs")
 164
 165 _cmifwarg("Package <Licenses> tag (pairs of <display_name> <file_path>)"
 166   STRING LICENSES "${${_cpifwrc}LICENSES_DEFAULT}")
 167
 168 if(${CMAKE_SYSTEM_NAME} MATCHES Windows)
 169   set(_CPACK_IFW_PACKAGE_ICON
 170       "set(CPACK_IFW_PACKAGE_ICON \"${CMake_SOURCE_DIR}/Source/QtDialog/CMakeSetup.ico\")")
 171   if(BUILD_QtDialog)
 172     set(_CPACK_IFW_SHORTCUT_OPTIONAL "${_CPACK_IFW_SHORTCUT_OPTIONAL}component.addOperation(\"CreateShortcut\", \"@TargetDir@/bin/cmake-gui.exe\", \"@StartMenuDir@/CMake (cmake-gui).lnk\");\n")
 173   endif()
 174   if(SPHINX_HTML)
 175     set(_CPACK_IFW_SHORTCUT_OPTIONAL "${_CPACK_IFW_SHORTCUT_OPTIONAL}component.addOperation(\"CreateShortcut\", \"@TargetDir@/doc/cmake-${CMake_VERSION_MAJOR}.${CMake_VERSION_MINOR}/html/index.html\", \"@StartMenuDir@/CMake Documentation.lnk\");\n")
 176   endif()
 177   if(CMake_BUILD_DEVELOPER_REFERENCE)
 178     if(CMake_BUILD_DEVELOPER_REFERENCE_HTML)
 179     set(_CPACK_IFW_SHORTCUT_OPTIONAL "${_CPACK_IFW_SHORTCUT_OPTIONAL}component.addOperation(\"CreateShortcut\", \"@TargetDir@/doc/cmake-${CMake_VERSION_MAJOR}.${CMake_VERSION_MINOR}/developer-reference/html/index.html\", \"@StartMenuDir@/CMake Developer Reference.lnk\");\n")
 180     endif()
 181   endif()
 182   install(FILES "${CMake_SOURCE_DIR}/Source/QtIFW/cmake.org.html"
 183     DESTINATION "${CMAKE_DOC_DIR}"
 184   )
 185 endif()
 186
 187 if(${CMAKE_SYSTEM_NAME} MATCHES Linux)
 188   set(CPACK_IFW_TARGET_DIRECTORY "@HomeDir@/${CMAKE_PROJECT_NAME}")
 189   set(CPACK_IFW_ADMIN_TARGET_DIRECTORY "@ApplicationsDir@/${CMAKE_PROJECT_NAME}")
 190 endif()
 191
 192 # Components scripts configuration
 193 if((EXISTS "${CMake_IFW_ROOT_COMPONENT_SCRIPT_TEMPLATE}")
 194   AND (NOT "${CMake_IFW_ROOT_COMPONENT_SCRIPT_GENERATED}" STREQUAL "")
 195   AND (NOT "${CMake_IFW_ROOT_COMPONENT_SCRIPT}"))
 196   cpack_ifw_configure_file("${CMake_IFW_ROOT_COMPONENT_SCRIPT_TEMPLATE}"
 197     "${CMake_IFW_ROOT_COMPONENT_SCRIPT_GENERATED}")
 198   _cmifwarg("Package <Script> tag"
 199     FILEPATH SCRIPT "${CMake_IFW_ROOT_COMPONENT_SCRIPT_GENERATED}")
 200 endif()
 201 foreach(_script
 202   CMake.Dialogs.QtGUI
 203   CMake.Documentation.SphinxHTML
 204   CMake.DeveloperReference.HTML)
 205   cpack_ifw_configure_file("${CMake_SOURCE_DIR}/Source/QtIFW/${_script}.qs.in"
 206     "${CMake_BINARY_DIR}/${_script}.qs")
 207 endforeach()
 208
 209 if(NOT DEFINED CPACK_PACKAGE_FILE_NAME)
 210   # if the CPACK_PACKAGE_FILE_NAME is not defined by the cache
 211   # default to source package - system, on cygwin system is not
 212   # needed
 213   if(CYGWIN)
 214     set(CPACK_PACKAGE_FILE_NAME "${CPACK_SOURCE_PACKAGE_FILE_NAME}")
 215   else()
 216     set(CPACK_PACKAGE_FILE_NAME
 217       "${CPACK_SOURCE_PACKAGE_FILE_NAME}-${CPACK_SYSTEM_NAME}")
 218   endif()
 219 endif()
 220
 221 set(CPACK_PACKAGE_CONTACT "cmake+development@discourse.cmake.org")
 222
 223 if(UNIX)
 224   set(CPACK_STRIP_FILES "${CMAKE_BIN_DIR}/ccmake;${CMAKE_BIN_DIR}/cmake;${CMAKE_BIN_DIR}/cpack;${CMAKE_BIN_DIR}/ctest")
 225   set(CPACK_SOURCE_STRIP_FILES "")
 226   set(CPACK_PACKAGE_EXECUTABLES "ccmake" "CMake")
 227 endif()
 228
 229 set(CPACK_WIX_UPGRADE_GUID "8ffd1d72-b7f1-11e2-8ee5-00238bca4991")
 230
 231 if(MSVC AND NOT "$ENV{WIX}" STREQUAL "")
 232   set(WIX_CUSTOM_ACTION_ENABLED TRUE)
 233   if(CMAKE_CONFIGURATION_TYPES)
 234     set(WIX_CUSTOM_ACTION_MULTI_CONFIG TRUE)
 235   else()
 236     set(WIX_CUSTOM_ACTION_MULTI_CONFIG FALSE)
 237   endif()
 238 else()
 239   set(WIX_CUSTOM_ACTION_ENABLED FALSE)
 240 endif()
 241
 242 # Set the options file that needs to be included inside CMakeCPackOptions.cmake
 243 set(QT_DIALOG_CPACK_OPTIONS_FILE ${CMake_BINARY_DIR}/Source/QtDialog/QtDialogCPack.cmake)
 244 configure_file("${CMake_SOURCE_DIR}/CMakeCPackOptions.cmake.in"
 245   "${CMake_BINARY_DIR}/CMakeCPackOptions.cmake" @ONLY)
 246 set(CPACK_PROJECT_CONFIG_FILE "${CMake_BINARY_DIR}/CMakeCPackOptions.cmake")
 247
 248 set(CPACK_SOURCE_IGNORE_FILES
 249   # Files specific to version control.
 250   "/\\\\.git/"
 251   "/\\\\.gitattributes$"
 252   "/\\\\.github/"
 253   "/\\\\.gitignore$"
 254   "/\\\\.hooks-config$"
 255
 256   # Cygwin package build.
 257   "/\\\\.build/"
 258
 259   # Temporary files.
 260   "\\\\.swp$"
 261   "\\\\.#"
 262   "/#"
 263   "~$"
 264   )
 265
 266 # include CPack model once all variables are set
 267 include(CPack)