3rdparty/ffmpeg/ffmpeg.cmake

   1 # Binary branch name: ffmpeg/master_20171009
   2 # Binaries were created for OpenCV: 8ac2c5d620b467d3f22802e96c88ddde6da707af
   3 set(FFMPEG_BINARIES_COMMIT "66b1fed06cf3510235f367f96aa26da5cb234a15")
   4 set(FFMPEG_FILE_HASH_BIN32 "3ae76b105113d944984b2351c61e21c6")
   5 set(FFMPEG_FILE_HASH_BIN64 "cf3bb5bc9d393b022ea7a42eb63e794d")
   6 set(FFMPEG_FILE_HASH_CMAKE "ec59008da403fb18ab3c1ed66aed583b")
   7
   8 function(download_win_ffmpeg script_var)
   9   set(${script_var} "" PARENT_SCOPE)
  10
  11   set(ids BIN32 BIN64 CMAKE)
  12   set(name_BIN32 "opencv_ffmpeg.dll")
  13   set(name_BIN64 "opencv_ffmpeg_64.dll")
  14   set(name_CMAKE "ffmpeg_version.cmake")
  15
  16   set(FFMPEG_DOWNLOAD_DIR "${OpenCV_BINARY_DIR}/3rdparty/ffmpeg")
  17
  18   set(status TRUE)
  19   foreach(id ${ids})
  20     ocv_download(FILENAME ${name_${id}}
  21                HASH ${FFMPEG_FILE_HASH_${id}}
  22                URL
  23                  "$ENV{OPENCV_FFMPEG_URL}"
  24                  "${OPENCV_FFMPEG_URL}"
  25                  "https://raw.githubusercontent.com/opencv/opencv_3rdparty/${FFMPEG_BINARIES_COMMIT}/ffmpeg/"
  26                DESTINATION_DIR ${FFMPEG_DOWNLOAD_DIR}
  27                ID FFMPEG
  28                RELATIVE_URL
  29                STATUS res)
  30     if(NOT res)
  31       set(status FALSE)
  32     endif()
  33   endforeach()
  34   if(status)
  35     set(${script_var} "${FFMPEG_DOWNLOAD_DIR}/ffmpeg_version.cmake" PARENT_SCOPE)
  36   endif()
  37 endfunction()