.svn/tmp/configure.ac.tmp

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.64)
   4
   5 AC_INIT([libffi], [3.0.8], [http://gcc.gnu.org/bugs.html])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AM_ENABLE_MULTILIB(, ..)
   9
  10 AC_CANONICAL_SYSTEM
  11 target_alias=${target_alias-$host_alias}
  12
  13 . ${srcdir}/configure.host
  14
  15 AM_INIT_AUTOMAKE
  16
  17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  18 # We must force CC to /not/ be precious variables; otherwise
  19 # the wrong, non-multilib-adjusted value will be used in multilibs.
  20 # As a side effect, we have to subst CFLAGS ourselves.
  21
  22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  24 AC_PROG_CC
  25 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  26
  27 AC_SUBST(CFLAGS)
  28
  29 AM_PROG_AS
  30 AM_PROG_CC_C_O
  31 AC_PROG_LIBTOOL
  32
  33 AM_MAINTAINER_MODE
  34
  35 AC_CHECK_HEADERS(sys/mman.h)
  36 AC_CHECK_FUNCS(mmap)
  37 AC_FUNC_MMAP_BLACKLIST
  38
  39 dnl The -no-testsuite modules omit the test subdir.
  40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  41
  42 TARGETDIR="unknown"
  43 case "$host" in
  44   alpha*-*-*)
  45         TARGET=ALPHA; TARGETDIR=alpha;
  46         # Support 128-bit long double, changable via command-line switch.
  47         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
  48         ;;
  49
  50   arm*-*-*)
  51         TARGET=ARM; TARGETDIR=arm
  52         ;;
  53
  54   amd64-*-freebsd*)
  55         TARGET=X86_64; TARGETDIR=x86
  56         ;;
  57
  58   cris-*-*)
  59         TARGET=LIBFFI_CRIS; TARGETDIR=cris
  60         ;;
  61
  62   frv-*-*)
  63         TARGET=FRV; TARGETDIR=frv
  64         ;;
  65
  66   hppa*-*-linux* | parisc*-*-linux*)
  67         TARGET=PA_LINUX; TARGETDIR=pa
  68         ;;
  69   hppa*64-*-hpux*)
  70         TARGET=PA64_HPUX; TARGETDIR=pa
  71         ;;
  72   hppa*-*-hpux*)
  73         TARGET=PA_HPUX; TARGETDIR=pa
  74         ;;
  75
  76   i386-*-freebsd* | i386-*-openbsd*)
  77         TARGET=X86_FREEBSD; TARGETDIR=x86
  78         ;;
  79   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw*)
  80         TARGET=X86_WIN32; TARGETDIR=x86
  81         ;;
  82   i?86-*-darwin*)
  83         TARGET=X86_DARWIN; TARGETDIR=x86
  84         ;;
  85   i?86-*-solaris2.1[[0-9]]*)
  86         TARGET=X86_64; TARGETDIR=x86
  87         ;;
  88   i?86-*-*)
  89         TARGET=X86; TARGETDIR=x86
  90         ;;
  91
  92   ia64*-*-*)
  93         TARGET=IA64; TARGETDIR=ia64
  94         ;;
  95
  96   m32r*-*-*)
  97         TARGET=M32R; TARGETDIR=m32r
  98         ;;
  99
 100   m68k-*-*)
 101         TARGET=M68K; TARGETDIR=m68k
 102         ;;
 103
 104   mips-sgi-irix5.* | mips-sgi-irix6.*)
 105         TARGET=MIPS; TARGETDIR=mips
 106         ;;
 107   mips*-*-linux*)
 108         TARGET=MIPS; TARGETDIR=mips
 109         ;;
 110
 111   moxie-*-*)
 112         TARGET=MOXIE; TARGETDIR=moxie
 113         ;;
 114
 115   powerpc*-*-linux* | powerpc-*-sysv*)
 116         TARGET=POWERPC; TARGETDIR=powerpc
 117         ;;
 118   powerpc-*-beos*)
 119         TARGET=POWERPC; TARGETDIR=powerpc
 120         ;;
 121   powerpc-*-darwin*)
 122         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
 123         ;;
 124   powerpc-*-aix* | rs6000-*-aix*)
 125         TARGET=POWERPC_AIX; TARGETDIR=powerpc
 126         ;;
 127   powerpc-*-freebsd*)
 128         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
 129         ;;
 130   powerpc*-*-rtems*)
 131         TARGET=POWERPC; TARGETDIR=powerpc
 132         ;;
 133
 134   s390-*-* | s390x-*-*)
 135         TARGET=S390; TARGETDIR=s390
 136         ;;
 137
 138   sh-*-* | sh[[34]]*-*-*)
 139         TARGET=SH; TARGETDIR=sh
 140         ;;
 141   sh64-*-* | sh5*-*-*)
 142         TARGET=SH64; TARGETDIR=sh64
 143         ;;
 144
 145   sparc*-*-*)
 146         TARGET=SPARC; TARGETDIR=sparc
 147         ;;
 148
 149   x86_64-*-darwin*)
 150         TARGET=X86_DARWIN; TARGETDIR=x86
 151         ;;
 152
 153   x86_64-*-cygwin* | x86_64-*-mingw*)
 154         TARGET=X86_WIN64; TARGETDIR=x86
 155         ;;
 156
 157   x86_64-*-*)
 158         TARGET=X86_64; TARGETDIR=x86
 159         ;;
 160 esac
 161
 162 AC_SUBST(AM_RUNTESTFLAGS)
 163
 164 if test $TARGETDIR = unknown; then
 165   AC_MSG_ERROR(["libffi has not been ported to $host."])
 166 fi
 167
 168 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
 169 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 170 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 171 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
 172 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
 173 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
 174 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
 175 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 176 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 177 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
 178 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 179 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 180 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 181 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 182 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
 183 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 184 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
 185 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
 186 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 187 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 188 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 189 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 190 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
 191 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
 192 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
 193
 194 AC_HEADER_STDC
 195 AC_CHECK_FUNCS(memcpy)
 196 AC_FUNC_ALLOCA
 197
 198 AC_CHECK_SIZEOF(double)
 199 AC_CHECK_SIZEOF(long double)
 200
 201 # Also AC_SUBST this variable for ffi.h.
 202 if test -z "$HAVE_LONG_DOUBLE"; then
 203   HAVE_LONG_DOUBLE=0
 204   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 205     if test $ac_cv_sizeof_long_double != 0; then
 206       HAVE_LONG_DOUBLE=1
 207       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 208     fi
 209   fi
 210 fi
 211 AC_SUBST(HAVE_LONG_DOUBLE)
 212
 213 AC_C_BIGENDIAN
 214
 215 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
 216     libffi_cv_as_cfi_pseudo_op, [
 217     libffi_cv_as_cfi_pseudo_op=unknown
 218     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
 219                    [libffi_cv_as_cfi_pseudo_op=yes],
 220                    [libffi_cv_as_cfi_pseudo_op=no])
 221 ])
 222 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
 223     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
 224               [Define if your assembler supports .cfi_* directives.])
 225 fi
 226
 227 if test x$TARGET = xSPARC; then
 228     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 229         libffi_cv_as_sparc_ua_pcrel, [
 230         save_CFLAGS="$CFLAGS"
 231         save_LDFLAGS="$LDFLAGS"
 232         CFLAGS="$CFLAGS -fpic"
 233         LDFLAGS="$LDFLAGS -shared"
 234         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 235                     [libffi_cv_as_sparc_ua_pcrel=yes],
 236                     [libffi_cv_as_sparc_ua_pcrel=no])
 237         CFLAGS="$save_CFLAGS"
 238         LDFLAGS="$save_LDFLAGS"])
 239     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 240         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 241                   [Define if your assembler and linker support unaligned PC relative relocs.])
 242     fi
 243
 244     AC_CACHE_CHECK([assembler .register pseudo-op support],
 245        libffi_cv_as_register_pseudo_op, [
 246        libffi_cv_as_register_pseudo_op=unknown
 247        # Check if we have .register
 248        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 249                        [libffi_cv_as_register_pseudo_op=yes],
 250                        [libffi_cv_as_register_pseudo_op=no])
 251     ])
 252     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 253        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 254                [Define if your assembler supports .register.])
 255     fi
 256 fi
 257
 258 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
 259     AC_CACHE_CHECK([assembler supports pc related relocs],
 260         libffi_cv_as_x86_pcrel, [
 261         libffi_cv_as_x86_pcrel=yes
 262         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 263         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 264             libffi_cv_as_x86_pcrel=no
 265         fi
 266         ])
 267     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
 268         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 269                   [Define if your assembler supports PC relative relocs.])
 270     fi
 271 fi
 272
 273 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 274     libffi_cv_ro_eh_frame, [
 275         libffi_cv_ro_eh_frame=no
 276         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 277         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 278             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 279                 libffi_cv_ro_eh_frame=yes
 280             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 281                  | grep -v '#write' > /dev/null; then
 282                 libffi_cv_ro_eh_frame=yes
 283             fi
 284         fi
 285         rm -f conftest.*
 286     ])
 287 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 288     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 289               [Define if .eh_frame sections should be read-only.])
 290     AC_DEFINE(EH_FRAME_FLAGS, "a",
 291               [Define to the flags needed for the .section .eh_frame directive.])
 292 else
 293     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 294               [Define to the flags needed for the .section .eh_frame directive.])
 295 fi
 296
 297 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 298     libffi_cv_hidden_visibility_attribute, [
 299         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 300         libffi_cv_hidden_visibility_attribute=no
 301         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 302             if grep '\.hidden.*foo' conftest.s >/dev/null; then
 303                 libffi_cv_hidden_visibility_attribute=yes
 304             fi
 305         fi
 306         rm -f conftest.*
 307     ])
 308 if test $libffi_cv_hidden_visibility_attribute = yes; then
 309     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 310               [Define if __attribute__((visibility("hidden"))) is supported.])
 311 fi
 312
 313 AH_BOTTOM([
 314 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 315 #ifdef LIBFFI_ASM
 316 #define FFI_HIDDEN(name) .hidden name
 317 #else
 318 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 319 #endif
 320 #else
 321 #ifdef LIBFFI_ASM
 322 #define FFI_HIDDEN(name)
 323 #else
 324 #define FFI_HIDDEN
 325 #endif
 326 #endif
 327 ])
 328
 329 AC_SUBST(TARGET)
 330 AC_SUBST(TARGETDIR)
 331
 332 AC_SUBST(SHELL)
 333
 334 AC_ARG_ENABLE(debug,
 335 [  --enable-debug          debugging mode],
 336   if test "$enable_debug" = "yes"; then
 337     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 338   fi)
 339
 340 AC_ARG_ENABLE(structs,
 341 [  --disable-structs       omit code for struct support],
 342   if test "$enable_structs" = "no"; then
 343     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 344   fi)
 345
 346 AC_ARG_ENABLE(raw-api,
 347 [  --disable-raw-api       make the raw api unavailable],
 348   if test "$enable_raw_api" = "no"; then
 349     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 350   fi)
 351
 352 AC_ARG_ENABLE(purify-safety,
 353 [  --enable-purify-safety  purify-safe mode],
 354   if test "$enable_purify_safety" = "yes"; then
 355     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 356   fi)
 357
 358 if test -n "$with_cross_host" &&
 359    test x"$with_cross_host" != x"no"; then
 360   toolexecdir='$(exec_prefix)/$(target_alias)'
 361   toolexeclibdir='$(toolexecdir)/lib'
 362 else
 363   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 364   toolexeclibdir='$(libdir)'
 365 fi
 366 multi_os_directory=`$CC -print-multi-os-directory`
 367 case $multi_os_directory in
 368   .) ;; # Avoid trailing /.
 369   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 370 esac
 371 AC_SUBST(toolexecdir)
 372 AC_SUBST(toolexeclibdir)
 373
 374 if test "${multilib}" = "yes"; then
 375   multilib_arg="--enable-multilib"
 376 else
 377   multilib_arg=
 378 fi
 379
 380 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 381 AC_CONFIG_COMMANDS(src, [
 382 test -d src || mkdir src
 383 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 384 ], [TARGETDIR="$TARGETDIR"])
 385
 386 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 387
 388 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile)
 389
 390 AC_OUTPUT