.svn/text-base/configure.ac.svn-base

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.64)
   4
   5 AC_INIT([libffi], [3.0.8], [http://gcc.gnu.org/bugs.html])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AM_ENABLE_MULTILIB(, ..)
   9
  10 AC_CANONICAL_SYSTEM
  11 target_alias=${target_alias-$host_alias}
  12
  13 . ${srcdir}/configure.host
  14
  15 AM_INIT_AUTOMAKE
  16
  17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  18 # We must force CC to /not/ be precious variables; otherwise
  19 # the wrong, non-multilib-adjusted value will be used in multilibs.
  20 # As a side effect, we have to subst CFLAGS ourselves.
  21
  22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  24 AC_PROG_CC
  25 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  26
  27 AC_SUBST(CFLAGS)
  28
  29 AM_PROG_AS
  30 AM_PROG_CC_C_O
  31 AC_PROG_LIBTOOL
  32
  33 AM_MAINTAINER_MODE
  34
  35 AC_CHECK_HEADERS(sys/mman.h)
  36 AC_CHECK_FUNCS(mmap)
  37 AC_FUNC_MMAP_BLACKLIST
  38
  39 dnl The -no-testsuite modules omit the test subdir.
  40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  41
  42 TARGETDIR="unknown"
  43 case "$host" in
  44   alpha*-*-*)
  45         TARGET=ALPHA; TARGETDIR=alpha;
  46         # Support 128-bit long double, changable via command-line switch.
  47         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
  48         ;;
  49
  50   arm*-*-*)
  51         TARGET=ARM; TARGETDIR=arm
  52         ;;
  53
  54   amd64-*-freebsd*)
  55         TARGET=X86_64; TARGETDIR=x86
  56         ;;
  57
  58   avr32*-*-*)
  59         TARGET=AVR32; TARGETDIR=avr32
  60         ;;
  61
  62   cris-*-*)
  63         TARGET=LIBFFI_CRIS; TARGETDIR=cris
  64         ;;
  65
  66   frv-*-*)
  67         TARGET=FRV; TARGETDIR=frv
  68         ;;
  69
  70   hppa*-*-linux* | parisc*-*-linux*)
  71         TARGET=PA_LINUX; TARGETDIR=pa
  72         ;;
  73   hppa*64-*-hpux*)
  74         TARGET=PA64_HPUX; TARGETDIR=pa
  75         ;;
  76   hppa*-*-hpux*)
  77         TARGET=PA_HPUX; TARGETDIR=pa
  78         ;;
  79
  80   i?86-*-freebsd* | i?86-*-openbsd*)
  81         TARGET=X86_FREEBSD; TARGETDIR=x86
  82         ;;
  83   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw*)
  84         TARGET=X86_WIN32; TARGETDIR=x86
  85         ;;
  86   i?86-*-darwin*)
  87         TARGET=X86_DARWIN; TARGETDIR=x86
  88         ;;
  89   i?86-*-solaris2.1[[0-9]]*)
  90         TARGET=X86_64; TARGETDIR=x86
  91         ;;
  92   i?86-*-*)
  93         TARGET=X86; TARGETDIR=x86
  94         ;;
  95
  96   ia64*-*-*)
  97         TARGET=IA64; TARGETDIR=ia64
  98         ;;
  99
 100   m32r*-*-*)
 101         TARGET=M32R; TARGETDIR=m32r
 102         ;;
 103
 104   m68k-*-*)
 105         TARGET=M68K; TARGETDIR=m68k
 106         ;;
 107
 108   mips-sgi-irix5.* | mips-sgi-irix6.*)
 109         TARGET=MIPS; TARGETDIR=mips
 110         ;;
 111   mips*-*-linux*)
 112         TARGET=MIPS; TARGETDIR=mips
 113         ;;
 114
 115   powerpc*-*-linux* | powerpc-*-sysv*)
 116         TARGET=POWERPC; TARGETDIR=powerpc
 117         ;;
 118   powerpc-*-beos*)
 119         TARGET=POWERPC; TARGETDIR=powerpc
 120         ;;
 121   powerpc-*-darwin*)
 122         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
 123         ;;
 124   powerpc-*-aix* | rs6000-*-aix*)
 125         TARGET=POWERPC_AIX; TARGETDIR=powerpc
 126         ;;
 127   powerpc-*-freebsd*)
 128         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
 129         ;;
 130   powerpc*-*-rtems*)
 131         TARGET=POWERPC; TARGETDIR=powerpc
 132         ;;
 133
 134   s390-*-* | s390x-*-*)
 135         TARGET=S390; TARGETDIR=s390
 136         ;;
 137
 138   sh-*-* | sh[[34]]*-*-*)
 139         TARGET=SH; TARGETDIR=sh
 140         ;;
 141   sh64-*-* | sh5*-*-*)
 142         TARGET=SH64; TARGETDIR=sh64
 143         ;;
 144
 145   sparc*-*-*)
 146         TARGET=SPARC; TARGETDIR=sparc
 147         ;;
 148
 149   x86_64-*-darwin*)
 150         TARGET=X86_DARWIN; TARGETDIR=x86
 151         ;;
 152
 153   x86_64-*-cygwin* | x86_64-*-mingw*)
 154         TARGET=X86_WIN64; TARGETDIR=x86
 155         ;;
 156
 157   x86_64-*-*)
 158         TARGET=X86_64; TARGETDIR=x86
 159         ;;
 160 esac
 161
 162 AC_SUBST(AM_RUNTESTFLAGS)
 163
 164 if test $TARGETDIR = unknown; then
 165   AC_MSG_ERROR(["libffi has not been ported to $host."])
 166 fi
 167
 168 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
 169 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 170 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 171 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
 172 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
 173 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
 174 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
 175 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 176 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 177 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
 178 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 179 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 180 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 181 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 182 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
 183 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 184 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
 185 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
 186 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
 187 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 188 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 189 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 190 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 191 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
 192 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
 193 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
 194
 195 AC_HEADER_STDC
 196 AC_CHECK_FUNCS(memcpy)
 197 AC_FUNC_ALLOCA
 198
 199 AC_CHECK_SIZEOF(double)
 200 AC_CHECK_SIZEOF(long double)
 201
 202 # Also AC_SUBST this variable for ffi.h.
 203 if test -z "$HAVE_LONG_DOUBLE"; then
 204   HAVE_LONG_DOUBLE=0
 205   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 206     if test $ac_cv_sizeof_long_double != 0; then
 207       HAVE_LONG_DOUBLE=1
 208       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 209     fi
 210   fi
 211 fi
 212 AC_SUBST(HAVE_LONG_DOUBLE)
 213
 214 AC_C_BIGENDIAN
 215
 216 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
 217     libffi_cv_as_cfi_pseudo_op, [
 218     libffi_cv_as_cfi_pseudo_op=unknown
 219     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
 220                    [libffi_cv_as_cfi_pseudo_op=yes],
 221                    [libffi_cv_as_cfi_pseudo_op=no])
 222 ])
 223 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
 224     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
 225               [Define if your assembler supports .cfi_* directives.])
 226 fi
 227
 228 if test x$TARGET = xSPARC; then
 229     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 230         libffi_cv_as_sparc_ua_pcrel, [
 231         save_CFLAGS="$CFLAGS"
 232         save_LDFLAGS="$LDFLAGS"
 233         CFLAGS="$CFLAGS -fpic"
 234         LDFLAGS="$LDFLAGS -shared"
 235         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 236                     [libffi_cv_as_sparc_ua_pcrel=yes],
 237                     [libffi_cv_as_sparc_ua_pcrel=no])
 238         CFLAGS="$save_CFLAGS"
 239         LDFLAGS="$save_LDFLAGS"])
 240     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 241         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 242                   [Define if your assembler and linker support unaligned PC relative relocs.])
 243     fi
 244
 245     AC_CACHE_CHECK([assembler .register pseudo-op support],
 246        libffi_cv_as_register_pseudo_op, [
 247        libffi_cv_as_register_pseudo_op=unknown
 248        # Check if we have .register
 249        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 250                        [libffi_cv_as_register_pseudo_op=yes],
 251                        [libffi_cv_as_register_pseudo_op=no])
 252     ])
 253     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 254        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 255                [Define if your assembler supports .register.])
 256     fi
 257 fi
 258
 259 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
 260     AC_CACHE_CHECK([assembler supports pc related relocs],
 261         libffi_cv_as_x86_pcrel, [
 262         libffi_cv_as_x86_pcrel=yes
 263         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 264         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 265             libffi_cv_as_x86_pcrel=no
 266         fi
 267         ])
 268     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
 269         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 270                   [Define if your assembler supports PC relative relocs.])
 271     fi
 272 fi
 273
 274 case "$target" in
 275      *-apple-darwin10* | *-*-freebsd* | *-*-openbsd* | *-pc-solaris*)
 276        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
 277                  [Cannot use malloc on this target, so, we revert to
 278                    alternative means])
 279      ;;
 280 esac
 281
 282 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 283     libffi_cv_ro_eh_frame, [
 284         libffi_cv_ro_eh_frame=no
 285         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 286         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 287             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 288                 libffi_cv_ro_eh_frame=yes
 289             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 290                  | grep -v '#write' > /dev/null; then
 291                 libffi_cv_ro_eh_frame=yes
 292             fi
 293         fi
 294         rm -f conftest.*
 295     ])
 296 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 297     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 298               [Define if .eh_frame sections should be read-only.])
 299     AC_DEFINE(EH_FRAME_FLAGS, "a",
 300               [Define to the flags needed for the .section .eh_frame directive.])
 301 else
 302     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 303               [Define to the flags needed for the .section .eh_frame directive.])
 304 fi
 305
 306 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 307     libffi_cv_hidden_visibility_attribute, [
 308         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 309         libffi_cv_hidden_visibility_attribute=no
 310         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 311             if grep '\.hidden.*foo' conftest.s >/dev/null; then
 312                 libffi_cv_hidden_visibility_attribute=yes
 313             fi
 314         fi
 315         rm -f conftest.*
 316     ])
 317 if test $libffi_cv_hidden_visibility_attribute = yes; then
 318     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 319               [Define if __attribute__((visibility("hidden"))) is supported.])
 320 fi
 321
 322 AH_BOTTOM([
 323 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 324 #ifdef LIBFFI_ASM
 325 #define FFI_HIDDEN(name) .hidden name
 326 #else
 327 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 328 #endif
 329 #else
 330 #ifdef LIBFFI_ASM
 331 #define FFI_HIDDEN(name)
 332 #else
 333 #define FFI_HIDDEN
 334 #endif
 335 #endif
 336 ])
 337
 338 AC_SUBST(TARGET)
 339 AC_SUBST(TARGETDIR)
 340
 341 AC_SUBST(SHELL)
 342
 343 AC_ARG_ENABLE(debug,
 344 [  --enable-debug          debugging mode],
 345   if test "$enable_debug" = "yes"; then
 346     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 347   fi)
 348
 349 AC_ARG_ENABLE(structs,
 350 [  --disable-structs       omit code for struct support],
 351   if test "$enable_structs" = "no"; then
 352     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 353   fi)
 354
 355 AC_ARG_ENABLE(raw-api,
 356 [  --disable-raw-api       make the raw api unavailable],
 357   if test "$enable_raw_api" = "no"; then
 358     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 359   fi)
 360
 361 AC_ARG_ENABLE(purify-safety,
 362 [  --enable-purify-safety  purify-safe mode],
 363   if test "$enable_purify_safety" = "yes"; then
 364     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 365   fi)
 366
 367 if test -n "$with_cross_host" &&
 368    test x"$with_cross_host" != x"no"; then
 369   toolexecdir='$(exec_prefix)/$(target_alias)'
 370   toolexeclibdir='$(toolexecdir)/lib'
 371 else
 372   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 373   toolexeclibdir='$(libdir)'
 374 fi
 375 multi_os_directory=`$CC -print-multi-os-directory`
 376 case $multi_os_directory in
 377   .) ;; # Avoid trailing /.
 378   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 379 esac
 380 AC_SUBST(toolexecdir)
 381 AC_SUBST(toolexeclibdir)
 382
 383 if test "${multilib}" = "yes"; then
 384   multilib_arg="--enable-multilib"
 385 else
 386   multilib_arg=
 387 fi
 388
 389 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 390 AC_CONFIG_COMMANDS(src, [
 391 test -d src || mkdir src
 392 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 393 ], [TARGETDIR="$TARGETDIR"])
 394
 395 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 396
 397 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile)
 398
 399 AC_OUTPUT